clear
set more off
// cd "" // set directory according to preference between "" if needed and uncomment
***********************************************
use paik_imc.dta, clear

***********************************************
//Original Presented Models (for coefs change "logistic" commands to "logit")
***********************************************
//Model1: BoT (Walt Balance of Threat)
logistic participate distance regime_distance_us power_target ///
	power i.war if (participate!=-1 & ccode!=740 & waryear==1)
//Model2: O/W (Joyce et al. Opportunity and Willingness)
logistic participate distance power regime_distance_subject ally_subject ///
	i.war if (participate!=-1 & ccode!=740 & waryear==1)
//Model3: Economic Dependence 
logistic participate trade_log ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1) 
//Model4: Security Dependence 
logistic participate ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1)	
//Model5: Dependence (Econ+Security)
logistic participate trade_log ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1)
	
***********************************************
//Alternate Models (1) (with CoW DV)
***********************************************	
logistic participate_cow distance regime_distance_us power_target ///
	power i.war if (participate_cow!=2 & ccode!=740 & waryear==1)
logistic participate_cow distance power regime_distance_subject ally_subject ///
	i.war if (participate_cow!=2 & ccode!=740 & waryear==1)
logistic participate_cow trade_log ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate_cow!=2 & ccode!=740 & waryear==1) 
logistic participate_cow ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate_cow!=2 & ccode!=740 & waryear==1)
logistic participate_cow trade_log ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate_cow!=2 & ccode!=740 & waryear==1)
	
***********************************************
//Alternate Models (2) (at start of war years)
***********************************************	
logistic participate distance regime_distance_us power_target ///
	power i.war if (participate!=-1 & ccode!=740 & waryear==1 & (year==1950|year==1965|year==1991|year==1999|year==2001|year==2003))
logistic participate distance power regime_distance_subject ally_subject ///
	i.war if (participate!=-1 & ccode!=740 & waryear==1 & (year==1950|year==1965|year==1991|year==1999|year==2001|year==2003))
logistic participate trade_log ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1 & (year==1950|year==1965|year==1991|year==1999|year==2001|year==2003)) 
logistic participate ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1 & (year==1950|year==1965|year==1991|year==1999|year==2001|year==2003))
logistic participate trade_log ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1 & (year==1950|year==1965|year==1991|year==1999|year==2001|year==2003))
	
***********************************************
//Marginal Effects (Overall)
***********************************************		
// Economic Dependence 
logistic participate trade_log ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1) 
margins, dydx(*) predict(pr)
//Security Dependence 
logistic participate ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1)	
margins, dydx(*) predict(pr) 
// BoT 
logistic participate distance regime_distance_us power_target ///
	power i.war if (participate!=-1 & ccode!=740 & waryear==1)
margins, dydx(*) predict(pr)
// O/W	
logistic participate distance power regime_distance_subject ally_subject ///
	i.war if (participate!=-1 & ccode!=740 & waryear==1)	
margins, dydx(*) predict(pr)

***********************************************
//Marginal Effects (by IV)
***********************************************		
//Trade
logistic participate trade_log ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1) 
margins, at (trade_log=(17(1)38)) predict(pr)
marginsplot, graphregion(color(white)) plotregion(color(white)) ///
	title("") xlabel(20 "25" 25 "25" 30 "30" 35 "35") ///
	ylabel(0(.2).8, nogrid) ///
	ytitle(Predicted Probability of Participation) xtitle(Trade with US (logged)) ///
	graphregion(color(white)) recastci(rarea) recast(line) ///
	ciopt(color(gray) fintensity(inten20) lstyle(dot) lwidth(vvthin) lcolor(white)) ///
	plotopt(color(black))	
//Alliance
logistic participate ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate!=-1 & ccode!=740 & waryear==1)
margins, at (ally=(0(1)1)) predict(pr)
marginsplot, recast(scatter) plotopts(msymbol(square) msize(large)) ///
	ciopts(msize(large)) ///
	xscale(range(-0.5 1.5)) title("") ///
	xlabel(0 "No Commitment from US" 1 "Commitment from US") ///
	ylabel(0(.1).3, nogrid) ///
	yline(.0687418, lwidth(vvthin) lpattern(dot)) ///
	yline(.2659315, lwidth(vvthin) lpattern(dot)) ///		
	xtitle("") ytitle(Predicted Probability of Participation) ///
	graphregion(color(white)) plotregion(color(white))	
//US Troops
logistic participate ally us_troops ///
	distance power regime_distance_us oil_exporter i.war ///
	if (participate_cow!=-1 & ccode!=740 & waryear==1)
margins, at (us_troops=(0(2)20)) predict(pr)
marginsplot, graphregion(color(white)) plotregion(color(white)) ///
	title("") xlabel(0(2)20) ylabel(0(.2)1, nogrid) yline(0, lpattern(dot) lcolor(black)) ///
	ytitle(Predicted Probability of Participation) xtitle(US Troops Deployed(ten thousands)) ///
	graphregion(color(white)) recastci(rarea) recast(line) ///
	ciopt(color(gray) fintensity(inten20) lstyle(dot) lwidth(vvthin) lcolor(white)) ///
	plotopt(color(black))	

***********************************************
//Trade Histogram
***********************************************		
twoway (histogram trade_log if year==1950, recast(line) lcolor(black) lpattern(solid) freq) ///
	(histogram trade_log if year==1965, recast(line) lcolor(blue) lpattern(dash) freq) ///
	(histogram trade_log if year==1991, recast(line) lcolor(red) lpattern(dot) freq) ///
	(histogram trade_log if year==1999, recast(line) lcolor(orange) lpattern(dash_dot) freq) ///
	(histogram trade_log if year==2001, recast(line) lcolor(green) lpattern(shortdash_dot) freq) ///	
	(histogram trade_log if year==2003, recast(line) lcolor(maroon) lpattern(longdash) freq), ///
	graphregion(color(white)) plotregion(color(white)) ///
	title("") ylabel(, nogrid) ///
	ytitle(Number of States) xtitle(Trade with US (log)) ///
	legend(label(1 "1950") label(2 "1965") label(3 "1991") label(4 "1999") label(5 "2001") ///
	label(6 "2003") rows(2)) 
	
***********************************************
//Korean Aid and Trade (Chapter4)
***********************************************		
twoway (tsline econ_aid_hist_mil if ccode==732 & year>=1953 & year<=1963 ///
	, lcolor(blue) lpattern(solid)) ///
	(tsline mil_aid_hist_mil if ccode==732 & year>=1953 & year<=1963 ///
	, lcolor(red) lpattern(dash)) ///
	(tsline trade_with_us if ccode==732 & year>=1953 & year<=1963 ///
	, lcolor(green) lpattern(longdash_dot_dot)), ///
	graphregion(color(white)) plotregion(color(white)) ///
	ytitle("Millions(Current US Dollars)") xtitle(Year) ///
	title("") subtitle("") ylabel(, nogrid) ///
	xlabel (1953(1)1963) ///
	legend(label(1 "Economic Aid") label(2 "Military Aid") label(3 "Trade")) ///
	note("")

***********************************************
//Aid to Korea (Chapter5)
***********************************************	
//1960-1968
twoway (tsline econ_aid_hist if (year>=1960 & year<=1968 & ccode==732) ///
	, lcolor(blue) lpattern(solid)) ///
	(tsline mil_aid_hist if (year>=1960 & year<=1968 & ccode==732) ///
	, lcolor(black) lpattern(longdash_dot_dot)) ///
	, graphregion(color(white)) plotregion(color(white)) ///	
	xlabel(1960(2)1968, nogrid) ///
	ylabel(100000 "100" 200000 "200" 300000 "300" 400000 "400", nogrid) ///
	xline(1965, lwidth(vvthin) lpattern(dash) lcolor(red)) ///	
	ytitle("") xtitle(Year) ///
	title("") subtitle("") ///
	legend(label(1 "Economic Aid(US Dollars, current millions)") ///
	label(2 "Military Aid(US Dollars, current millions)") cols(1)) ///
	note("")
//1960-1980
twoway (tsline econ_aid_hist if (year>=1960 & year<=1980 & ccode==732) ///
	, lcolor(blue) lpattern(solid)) ///
	(tsline mil_aid_hist if (year>=1960 & year<=1980 & ccode==732) ///
	, lcolor(black) lpattern(longdash_dot_dot)) ///
	, graphregion(color(white)) plotregion(color(white)) ///	
	xlabel(1960(5)1980, nogrid) ///
	ylabel(200000 "200" 400000 "400" 600000 "600" 800000 "800", nogrid) ///
	xline(1965, lwidth(vvthin) lpattern(dash) lcolor(red)) ///
	xline(1973, lwidth(vvthin) lpattern(dash) lcolor(red)) ///	
	ytitle("") xtitle(Year) ///
	title("") subtitle("") ///
	legend(label(1 "Economic Aid(US Dollars, current millions)") ///
	label(2 "Military Aid(US Dollars, current millions)") cols(1)) ///
	note("")
***********************************************
//Aid to Vietnam Participants (Chapter5)
***********************************************	
twoway (tsline mil_aid_hist if (ccode==230 & year>=1965 & year<=1970) ///
	, lcolor(blue) lpattern(dash)) ///
	(tsline mil_aid_hist if (ccode==732 & year>=1965 & year<=1970) ///
	, lcolor(black) lpattern(solid)) ///
	(tsline mil_aid_hist if (ccode==800 & year>=1965 & year<=1970) ///
	, lcolor(dkgreen) lpattern(dot)) ///
	(tsline mil_aid_hist if (ccode==840 & year>=1965 & year<=1970) ///
	, lcolor(dknavy) lpattern(dash_dot)) ///
	(tsline mil_aid_hist if (ccode==900 & year>=1965 & year<=1970) ///
	, lcolor(lime) lpattern(shortdash)) ///
	(tsline mil_aid_hist if (ccode==920 & year>=1965 & year<=1970) ///
	, lcolor(maroon) lpattern(longdash)), ///
	graphregion(color(white)) plotregion(color(white)) ///	
	xlabel(1965(1)1970, nogrid) ///
	ylabel(200000 "200" 400000 "400" 600000 "600", nogrid) ///
	ytitle("Military Aid(US Dollars, current millions)") xtitle("Year") ///
	title("") subtitle("") note("") ///
	legend(label(1 "Spain") label(2 "S.Korea") label(3 "Thailand") ///
	label(4 "Philippines") label(5 "Australia") label(6 "New Zealand") cols(2))
//alternate standardized aid to participants
twoway (tsline milaid1965 if (ccode==230 & year>=1965 & year<=1970) ///
	, lcolor(blue) lpattern(dash)) ///
	(tsline milaid1965 if (ccode==732 & year>=1965 & year<=1970) ///
	, lcolor(black) lpattern(solid)) ///
	(tsline milaid1965 if (ccode==800 & year>=1965 & year<=1970) ///
	, lcolor(dkgreen) lpattern(dot)) ///
	(tsline milaid1965 if (ccode==840 & year>=1965 & year<=1970) ///
	, lcolor(dknavy) lpattern(dash_dot)) ///
	(tsline milaid1965 if (ccode==900 & year>=1965 & year<=1970) ///
	, lcolor(lime) lpattern(shortdash)), ///
	graphregion(color(white)) plotregion(color(white)) ///	
	xlabel(1965(1)1970, nogrid) xtitle("Year") ///
	ylabel(, nogrid) ///
	ytitle("Military Aid(Percentage Change from 1965)") ///
	title("") subtitle("") note("") ///
	legend(label(1 "Spain") label(2 "S.Korea") label(3 "Thailand") ///
	label(4 "Philippines") label(5 "Australia") cols(2))

***********************************************
//OLS Regressions(Chapter5)
***********************************************	
reg military_aid_1 participant milex_1 regime_distance_us ally ///
	i.period if (term==1 & participant!=-1)
margins, dydx(participant) post 
est store maid1
reg military_aid_2 participant milex_2 regime_distance_us ally ///
	i.period if (term==2 & participant!=-1)
margins, dydx(participant) post 
est store maid2
reg military_aid_3 participant milex_3 regime_distance_us ally ///
	i.period if (term==3 & participant!=-1)
margins, dydx(participant) post 
est store maid3
coefplot ///
	(maid1, msymbol(square) msize(large) mcolor(black) ///
	ciopt(color(black) lpattern(dot)) ///
	label(Mid War)) ///
	(maid2, msymbol(square) msize(large) mcolor(gs10) ///
	ciopt(color(gs10) lpattern(dash)) ///
	label(End War)) ///
	(maid3, msymbol(square) msize(large) mcolor(black) mfcolor(white) ///
	ciopt(color(black) lpattern(solid)) ///
	label(Long Term)), ///
	xline(0, lwidth(vvthin) lpattern(solid) lcolor(red)) ///
	ylabel("") ytitle(Timeframe)  ///
	xtitle("Change in Military Aid(US Dollars, 2012 constant millions)") ///
	xlabel(-200(100)300, nogrid) /// 
	graphregion(color(white)) legend(rows(1)) 

//Alternate OLS Model (1): In Consideration of Thailand Entry Point. MP change to 1969 (from 67)
reg military_aid_1 participant milex_1 regime_distance_us ally ///
	i.period if (term2==1 & participant!=-1)
reg military_aid_2 participant milex_2 regime_distance_us ally ///
	i.period if (term2==2 & participant!=-1)
reg military_aid_3 participant milex_3 regime_distance_us ally ///
	i.period if (term2==3 & participant!=-1)

//Alternate OLS Model (2): No Kosovo
reg military_aid_1 participant milex_1 regime_distance_us ally ///
	i.period if (term3==1 & participant!=-1)
reg military_aid_2 participant milex_2 regime_distance_us ally ///
	i.period if (term3==2 & participant!=-1)
reg military_aid_3 participant milex_3 regime_distance_us ally ///
	i.period if (term3==3 & participant!=-1)